<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Specio::Exporter;

use strict;
use warnings;

our $VERSION = '0.46';

use parent 'Exporter';

use Specio::Helpers qw( install_t_sub );
use Specio::Registry
    qw( exportable_types_for_package internal_types_for_package register );

my %Exported;

sub import {
    my $package  = shift;
    my $reexport = shift;

    my $caller = caller();

    return if $Exported{$caller}{$package};

    my $exported = exportable_types_for_package($package);

    while ( my ( $name, $type ) = each %{$exported} ) {
        register( $caller, $name, $type-&gt;clone, $reexport );
    }

    install_t_sub(
        $caller,
        internal_types_for_package($caller),
    );

    if ( $package-&gt;can('_also_export') ) {
        for my $sub ( $package-&gt;_also_export ) {
            ## no critic (TestingAndDebugging::ProhibitNoStrict)
            no strict 'refs';
            *{ $caller . '::' . $sub } = \&amp;{ $package . '::' . $sub };
        }
    }

    $Exported{$caller}{$package} = 1;

    return;
}

1;

# ABSTRACT: Base class for type libraries

__END__

=pod

=encoding UTF-8

=head1 NAME

Specio::Exporter - Base class for type libraries

=head1 VERSION

version 0.46

=head1 SYNOPSIS

    package MyApp::Type::Library;

    use parent 'Specio::Exporter';

    use Specio::Declare;

    declare( ... );

    # more types here

    package MyApp::Foo;

    use MyApp::Type::Library

=head1 DESCRIPTION

Inheriting from this package makes your package a type exporter. By default,
types defined in a package are never visible outside of the package. When you
inherit from this package, all the types you define internally become
available via exports.

The exported types are available through the importing package's C&lt;t&gt;
subroutine.

By default, types your package imports are not re-exported:

  package MyApp::Type::Library;

  use parent 'Specio::Exporter';

  use Specio::Declare;
  use Specio::Library::Builtins;

In this case, the types provided by L&lt;Specio::Library::Builtins&gt; are not
exported to packages which C&lt;use MyApp::Type::Library&gt;.

You can explicitly ask for types to be re-exported:

  package MyApp::Type::Library;

  use parent 'Specio::Exporter';

  use Specio::Declare;
  use Specio::Library::Builtins -reexport;

In this case, packages which C&lt;use MyApp::Type::Library&gt; will get all the
types from L&lt;Specio::Library::Builtins&gt; as well as any types defined in
C&lt;MyApp::Type::Library&gt;.

=head1 ADDITIONAL EXPORTS

If you want to export some additional subroutines from a package which has
C&lt;Specio::Exporter&gt; as its parent, define a sub named C&lt;_also_export&gt;. This
sub should return a I&lt;list&gt; of subroutines defined in your package that should
also be exported. These subs will be exported unconditionally to any package
that uses your package.

=head1 COMBINING LIBRARIES WITH L&lt;Specio::Subs&gt;

You can combine loading libraries with subroutine generation using
L&lt;Specio::Subs&gt; by using C&lt;_also_export&gt; and
C&lt;Specio::Subs::subs_installed_into&gt;:

    package My::Library;

    use My::Library::Internal -reexport;
    use Specio::Library::Builtins -reexport;
    use Specio::Subs qw( My::Library::Internal Specio::Library::Builtins );

    sub _also_export {
        return Specio::Subs::subs_installed_into(__PACKAGE__);
    }

=head1 SUPPORT

Bugs may be submitted at L&lt;https://github.com/houseabsolute/Specio/issues&gt;.

I am also usually active on IRC as 'autarch' on C&lt;irc://irc.perl.org&gt;.

=head1 SOURCE

The source code repository for Specio can be found at L&lt;https://github.com/houseabsolute/Specio&gt;.

=head1 AUTHOR

Dave Rolsky &lt;autarch@urth.org&gt;

=head1 COPYRIGHT AND LICENSE

This software is Copyright (c) 2012 - 2020 by Dave Rolsky.

This is free software, licensed under:

  The Artistic License 2.0 (GPL Compatible)

The full text of the license can be found in the
F&lt;LICENSE&gt; file included with this distribution.

=cut
</pre></body></html>